Ciao!
Sono incappato in Programming:Unlocking ASIC. Che roba forte che c’è in quelle routine ottimizzate! ![]()
Ed ecco i miei 2 centesimi sulla questione.
Come menzionato nella discussione sul vecchio forum collegata, è responsabilità del chiamante
gestire gli interrupt, quindi via tutti i DI/EI! -2 byte
Come promemoria, la sequenza completa di sblocco RMR2 da scrivere sulla porta I/O #BCxx è:
NZB, #00,#FF,#77...#8A, STATE (#CD), EOK
NZB: Qualsiasi valore tranne zero.
STATE: #CD sblocca (qualunque altro valore bloccherà).
EOK: Deve essere inviato per far uscire l’ASIC dalla sequenza di sblocco e ripristinare la selezione del registro CRTC I/O. Può essere qualsiasi valore.
La classica routine ottimizzata non sfrutta alcune proprietà della sequenza di sblocco. Come ad esempio:
- Mettiamo i dati della sequenza subito dopo la fine della routine, con un
RET, cioè un opcode&C9, non zero… mmm, mi puzza proprio diNZB! : -1 byte - Perché memorizzare il valore
EOKnei dati della sequenza? Non ci importa quale sia il suo valore, invieremo semplicemente qualsiasi cosa troviamo: -1 byte
Questo ci dà una versione leggermente più compatta:
; Send a 17 bytes sequence to I/O port #BCxx to unlock RMR2
; register access. KISS approach using a table of raw values.
;
; Size: 28 bytes
; Time: 178 µs
;
; Output:
; BC=&BC00
; Trashes HL and Flags
rmr2_unlock:
ld bc,&BC00+17
ld hl,_rmr2_data_key
_rmr2_send_key inc b
outi
dec c
jr nz,_rmr2_send_key
_rmr2_data_key ret ; This opcode is also used as SYNC/NZB value (#C9)
db 0, &FF,&77,&B3,&51,&A8,&D4,&62,&39,&9C,&46,&2B,&15,&8A
_rmr2_data_lock db 205 ; 205 to Unlock, anything else to lock
; The routine will over-read one byte at this location
; to retrieve an EOK value, necessary for proper unlocking.
E ora, con i suoi 28 byte di lunghezza, questa routine in pieno stile KISS fa sembrare quelle ottimizzate… Beh, dai, non importa! (vi vogliamo bene lo stesso!)
Ma la routine di re-implementazione LFSR fatta da @Urusergi mi ha fatto fremere il naso. Ci sono così tanti modi e giochetti con i bit per implementare questa piccolissima cosa LFSR, che potrebbero esserci delle varianti ancora più corte là fuori…
…qualche giorno, pianti e sangue dal naso dopo: beh, a quanto pare non così tante!
Ne ho trovata solo una:
; Software re-implementation of the LFSR logic described in
; the Amstrad Patent (GB2243701A). It generates a 15 bytes
; sequence as verified by the ASIC to unlock RMR2 access.
;
; Designed by Urusergi
; Modified by Grim (shaving a single byte, pfew!)
;
; Size: 27 bytes
; Time: 389 µs
;
; Output:
; BC=&BCFF
; Trashes HL and AF
rmr2_unlock:
ld bc,&BCFF
out (c),c ; SYNC/NZB
out (c),0 ; SYNC/NUL
ld a,c
_rmr2_send_key
out (c),a
ld h,a
add hl,hl
rra
add hl,hl
ld l,a
xor h
and &F7
xor l
add a,h
and &88
xor l
cp c
jr nz,_rmr2_send_key
ret
Ho cercato di eliminare il (carino) test di uscita cp c e usare qualche flag dopo l’ultimo xor l, ma finora senza successo. Il cp c resiste! ![]()